[toc]

AlGaAs/GaAs HEMT 的雪崩击穿模拟

本例演示了单量子阱晶格匹配 AlGaAs/GaAs HEMT 的雪崩击穿模拟，主要内容包括：

• 使用 Atlas 语法构建异质结结构
• 材料与模型参数的设定
• Id–Vds 与击穿特性的模拟
• 使用 TonyPlot 显示结果

所研究的器件包括：

• 高掺杂（1×10¹⁸ cm⁻³）的 AlGaAs 层，Al 组分为 0.3；
• 厚度为 250 Å、掺杂浓度为 1×10¹⁵ cm⁻³ 的 GaAs 通道层；
• 与通道相同掺杂的 AlGaAs 缓冲层。
  在源极和漏极下方的通道部分为重掺杂，源漏电极垂直接触通道区。这种方式能够考虑接触材料的合金化以及载流子通过异质结的隧穿效应。通道长度为 0.5 μm。

输入文件内容

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

go atlas

# 给仿真或绘图添加标题
Title HEMT breakdown characteristics
# 网格
mesh

x.mesh loc=0.00 spac=0.025
x.mesh loc=0.75 spac=0.025

y.mesh loc=-0.02 spac=0.01
y.mesh loc=0.00 spac=0.01
y.mesh loc=0.03 spac=0.001
y.mesh loc=0.0425 spac=0.01
y.mesh loc=0.055 spac=0.001
y.mesh loc=0.2 spac=0.05

# 区域位置
region num=1 material=GaAs y.min=0.03 y.max=0.055
# Al 的组分比例（x.composition=0.3）
region num=2 material=AlGaAs y.max=0.03 x.composition=0.3
region num=3 material=AlGaAs y.min=0.055 x.composition=0.3
# 人工氧化层,以便通过 interface 语句指定 AlGaAs 表面态。
region num=4 material=Oxide y.min=-0.02 y.max=0.0

# 定义电极

elec num=1 name=source x.min=0.00 x.max=0.00 y.min=0.0 y.max=0.05
elec num=2 name=gate   x.min=0.10 x.max=0.60 y.min=0.0 y.max=0.00
elec num=3 name=drain  x.min=0.75 x.max=0.75 y.min=0.0 y.max=0.05

# 掺杂
doping uniform y.min=0 y.max=0.03 n.type conc=1e18
doping uniform y.min=0.03 n.type conc=1e15
doping uniform x.min=0.00 x.max=0.05 y.min=0.03 y.max=0.05 n.type conc=1e18
doping uniform x.min=0.70 x.max=0.75 y.min=0.03 y.max=0.05 n.type conc=1e18

# 指定氧化物和AlGaAs的界面特性，qf界面电荷密度
interface x.min=0 x.max=0.75 y.min=-0.01 y.max=0.005 qf=-1e12

# 材料参数
# 设置所有材料的电子、空穴SRH复合寿命
material taun0=1e-9 taup0=1e-9
# 直接设置电子、空穴低场迁移率（cm²/V·s）和300K下有效态密度（cm⁻³）
# 低场指的是电子/空穴漂移速度与电场呈线性关系，高场时漂移速度会趋于饱和
material material=AlGaAs mun=2000 mup=350 nc300=5.7e17
material align = 0.6

# 模型设置电场依赖的迁移率(field-dependent mobility)模型 和 SRH 复合模型
model fldmob srh
# 打开浓度依赖迁移率模型，只对 GaAs 区域生效
model material=GaAs conmob
# 启用 Selberherr 冲击电离模型，设置的这些数值基本来自实验或文献拟合。
# 分别为电子和空穴设置电离率参数（两组相同），并用 egran 和 beta 参数对高场行为进行修正
impact  selb an1=1.899e5 bn1=5.75e5 ap1=2.215e5 bp1=6.57e5 \
an2=1.899e5 bn2=5.75e5 ap2=2.215e5 bp2=6.57e5 egran=1.e20 betan=1.82 betap=1.75
# 接触电极，栅极功函数设置
contact  name=gate workfun=4.73 

# 指定方法，初始条件或低偏压时gummel更稳定，启用陷阱态相关方程
method gummel  newton itlim=20 trap  maxtrap=6   
# 输出导带、价带能量分布
output con.band val.band

# 指定栅极电压 (Vgate) 为 0 V，即对器件在栅极接地条件下进行偏置求解,常用于初始化
solve vgate=0
save outf=hemtex02_0.str
tonyplot hemtex02_0.str -set hemtex02_0.set
# master 代表输出更全的信息
log outf=hemtex02.log master
# 漏电压扫描求解
solve vdrain=0.025 vstep=0.025 vfinal=0.4 name=drain
# 貌似关键字顺序可以变
method newton trap itlim=35 maxtrap=6
# compl表示电流收敛的全局容差（complementary tolerance）/ e.comp 电子电流的收敛容差因子
solve vdrain=0.50  vstep=0.25 name=drain vfinal=10 compl=1e-3 e.comp=3

tonyplot  hemtex02.log  -set hemtex02.set 

quit

理解输入代码

• interface x.min=0 x.max=0.75 y.min=-0.01 y.max=0.005 qf=-1e12

  • Silvaco Atlas/Blaze 中用来定义 界面特性 (interface properties) 的语句

  • interface：定义一个界面（通常是两种材料的交界，比如 GaAs/AlGaAs，或半导体/氧化层）。

  • x.min=0, x.max=0.75, y.min=-0.01, y.max=0.005
    → 确定界面作用的空间范围（矩形区域）。
    也就是说，这个界面条件只在 x 从 0 到 0.75 μm，y 从 -0.01 到 0.005 μm 的区域有效。

  • qf=-1e12
    → 表示界面电荷密度 (fixed interface charge density) ，单位是 cm⁻²。
    这里的 -1e12 意味着在该界面上存在 负的固定电荷密度 1×10¹² cm⁻²。

  • 在半导体器件模拟中，界面固定电荷 会显著影响能带弯曲、电场分布和载流子输运。

  • 例如，在 HEMT 结构的 AlGaAs/GaAs 界面处，这类电荷可以模拟由于表面态或界面态引入的电荷，从而改变沟道的电子浓度。

  • 负的固定电荷 (qf < 0) 通常会吸引电子，增强沟道中的 2DEG（二维电子气）。

• material material=AlGaAs mun=2000 mup=350 nc300=5.7e17

  • material=AlGaAs
    → 指定要定义的材料是 AlGaAs（铝镓砷）。这行语句对 AlGaAs 层生效，不会影响 GaAs 或其他材料。

  • mun=2000
    → 设定 电子低场迁移率 (electron mobility, μₙ) = 2000 cm²/V·s。
    这是模型里的常数值，不随掺杂或温度变化（除非另开 mobility models）。

  • mup=350
    → 设定 空穴低场迁移率 (hole mobility, μₚ) = 350 cm²/V·s。

  • nc300=5.7e17
    → 指定在 300 K 下，导带的有效态密度 (conduction band density of states) = 5.7 × 10¹⁷ cm⁻³。
    这是决定载流子浓度、费米能级位置等的重要参数。

  • 这条语句的作用就是 覆盖 Atlas 的默认材料参数，用用户给定的迁移率和态密度来替代库里的默认值。

    • 对 HEMT 模拟来说，AlGaAs 层的 载流子迁移率 和 能带参数 会直接影响沟道的电子浓度、漂移速度和击穿电场分布
    • nc300 影响载流子统计：在给定的费米能级下，电子浓度 $n=N_c⋅F_{1/2}((E_f−E_c)/kT)$。因此修改它会改变电子分布和器件电流。

• model fldmob srh

  • fldmob (field-dependent mobility)
    → 打开 电场依赖的迁移率模型。
    • 在低场时，迁移率等于你在 material 中定义的 低场迁移率。
    • 在高场时，载流子速度会逐渐趋近于 饱和漂移速度 vsatv_{sat}vsat，从而修正迁移率。
    • 这样才能正确模拟高场下的器件特性（比如 HEMT、MOSFET 饱和区）。
  • srh (Shockley-Read-Hall recombination)
    → 打开 SRH 复合模型。
    • 描述载流子通过 深能级陷阱（缺陷态、杂质能级） 的复合过程。
    • 计算中会用到 taun0（电子寿命）、taup0（空穴寿命）等参数

• impact  selb an1=1.899e5 bn1=5.75e5 ap1=2.215e5 bp1=6.57e5 \
  an2=1.899e5 bn2=5.75e5 ap2=2.215e5 bp2=6.57e5 egran=1.e20 betan=1.82 betap=1.75
  

  • 这行代码是 Avalanche Breakdown（雪崩击穿）仿真里启用冲击电离模型 的设置

  • impact selb

    • impact：启用 impact ionization model（冲击电离/雪崩产生模型）。

    • selb：表示使用 Selberherr 模型。这是 TCAD 里常用的冲击电离经验模型。

    • 电离率形式为：

      $α(E)=A \cdot \exp\left(-\frac{B}{E}\right)$

      其中 $α(E)$ = 电离系数，$E$ = 电场强度，$A、B$ 是拟合参数。

  • an1, bn1：电子的 Selberherr 模型参数 (region 1)。

    • an1=1.899e5 → Aₙ 系数，bn1=5.75e5 → Bₙ 系数，共同决定电子的电离率随电场的变化。

  • ap1, bp1：空穴的 Selberherr 模型参数 (region 1)

  • an2, bn2, ap2, bp2：和上面一样，只不过是 region 2 的参数，有时在异质结或者不同材料区域需要分区定义电离参数，所以有 1 和 2 两组。

  • egran=1.e20

    • 用于能量平衡或高场下的 能量粒化参数，限制能量增益。
    • 避免数值发散，属于数值稳定性相关的参数。

  • betan=1.82, betap=1.75

    • 电离系数的修正指数，用来调节 Selberherr 模型在高场下的拟合精度。
    • βₙ 作用于电子，βₚ 作用于空穴

模拟结果

净掺杂浓度	漏极电压/电流